override public function action():int
{
    // 弾を撃つ
    var action:int = Command.FIRE;
    // タンクを前進させる.
    action |= Command.TANK_MOVE_FORWARD;
    
    // 敵の位置を取得
    var enemyPos:WVector2D = _scene.enemyTankPosition;
    // 自分の位置を取得
    var myPos:WVector2D = _scene.myTankPosition;
    
    // 自分の位置からみた敵の位置を取得
    enemyPos.subtract(myPos);
    // 自分の位置からみた敵の位置を方角に直す
    var angle:Number = Math.atan2(enemyPos.y, enemyPos.x);
    // 自分の砲台が向いている方角と敵の方角との差をとる
    angle -= (_scene.myGunAngle + _scene.myTankAngle);
    
    // 角度を0～2πに直す.
    angle = WMath.modulo2PI(angle);
    
    // 砲台を適切な角度に向ける.
    
    // 角度が180度以下なら敵は砲台より右側にいる.
    if (angle < Math.PI) action |= Command.GUN_TURN_RIGHT;
    // 角度が180度以上ということは敵は砲台より左側にいる.
    else if (angle > Math.PI) action |= Command.GUN_TURN_LEFT;
    
    return action;
}
         

private var _spBattery:Sprite;                                         // 砲台のグラフィック
private var _spTank:Sprite;                                            // 戦車のグラフィック
private var _mat:Matrix;                                               // drawメソッドでの表示位置の調整用
private var _ctfm:ColorTransform = new ColorTransform(1, 1, 1, 0);     // BitmapDataを消去する

override public function draw(bitmapData:BitmapData):void
{
    // 砲台を回転させる.
    // _spTank.addChild(_spBattery);
    _spBattery.rotation = _scene.myGunAngle * 180 / Math.PI;
    
    // タンクの座標と傾きをセットする
    _mat.identity();
    _mat.rotate(_scene.myTankAngle);
    _mat.translate(_scene.myTankPosition.x, _scene.myTankPosition.y);
    
    // bitmapDataを一旦クリアする
    bitmapData.colorTransform(bitmapData.rect, _ctfm);
    // bitmapDataを描画する
    bitmapData.draw(_spTank, _mat, null, null, null, true);
}